Exercício - Repetição - Resp

Prévia do material em texto

Lista de Exercícios 3- Estrutura Repetição: 
 
1- Criar um algoritmo que imprima a soma de todos os números de 1 até 100. 
 
ALGORITMO "EX1" 
 VAR 
 SOMA, X : INTEIRO 
INICIO 
 SOMA := 0 
 PARA X DE 1 ATE 100 FACA 
 SOMA := SOMA + X 
 FIMPARA 
 ESCREVAL ("SOMATÓRIO: ", SOMA) 
FIMALGORITMO 
 
2- Criar um algoritmo que entre com cem números e imprima o quadrado de cada número. 
 
ALGORITMO "EX2" 
 VAR 
 X : INTEIRO 
 NUM, Q : REAL 
INICIO 
 PARA X DE 1 ATE 100 FACA 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 Q := NUM ^ 2 
 ESCREVAL ("QUADRADO: ", Q) 
 FIMPARA 
FIMALGORITMO 
 
3- Ler vários números e informar quantos números entre 100 e 200 foram digitados. Quando o valor zero for lido, 
o algoritmo deverá cessar sua execução. 
 
ALGORITMO "EX3" 
VAR 
QN : INTEIRO 
NUM : REAL 
INICIO 
 QN := 0 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 ENQUANTO NUM <> 0 FACA 
 SE (NUM > 100) E (NUM < 200) ENTAO 
 QN := QN + 1 
 FIMSE 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 FIMENQUANTO 
 ESCREVAL ("QUANTIDADE NÚMEROS: ", QN) 
FIMALGORITMO 
 
 
4- Criar um algoritmo que imprima todos os números pares de 1 até 100. 
 
ALGORITMO "EX4" 
 VAR 
 X, R : INTEIRO 
INICIO 
 PARA X DE 1 ATE 100 FACA 
 R := X MOD 2 
SE R = 0 ENTAO 
 ESCREVAL ("NÚMERO PAR: ", X) 
 FIMSE 
 FIMPARA 
FIMALGORITMO 
 
5- Criar um algoritmo que entre com a profissão de várias pessoas e imprima quantos são Programadores. 
Quando o valor “fim” for lido, o algoritmo deverá cessar sua execução. 
 
ALGORITMO "EX5" 
VAR 
 QP : INTEIRO 
 PROF : CARACTERE 
INICIO 
 QP := 0 
 ESCREVAL ("ENTRE COM A PROFISSÃO: ") 
 LEIA (PROF) 
 ENQUANTO PROF <> "FIM" FACA 
 SE PROF = "PROGRAMADOR" ENTAO 
 QP := QP + 1 
 FIMSE 
 ESCREVAL ("ENTRE COM A PROFISSÃO: ") 
 LEIA (PROF) 
 FIMENQUANTO 
 ESCREVAL ("QUANTIDADE DE PROGRAMADORES: ", QP) 
FIMALGORITMO 
 
6- Criar um algoritmo que entre com o sexo de várias pessoas (M / F) e imprima o total de pessoas do sexo 
masculino e total de pessoas do sexo feminino. Quando o valor “P” for lido, o algoritmo deverá cessar sua 
execução. 
 
ALGORITMO "EX6" 
 VAR 
 TSM, TSF: INTEIRO 
 SEXO : CARACTERE 
INICIO 
 TSM := 0 
TSF := 0 
 ESCREVAL ("DIGITE O SEXO (M/F):") 
LEIA (SEXO) 
 ENQUANTO SEXO <> "P" FACA 
 SE SEXO = "M" ENTAO 
 TSM := TSM + 1 
 SENAO 
 TSF := TSF + 1 
 FIMSE 
 ESCREVAL ("DIGITE O SEXO (M/F):") 
LEIA (SEXO) 
 FIMENQUANTO 
 ESCREVAL ("TOTAL DO SEXO MASCULINO: ", TSM) 
 ESCREVA ("TOTAL DO SEXO FEMININO: ", TSF) 
FIMALGORITMO 
 
7- Criar um algoritmo que entre com o nome, idade e sexo de 200 pessoas (M / F). Imprimir o nome se a pessoa 
for do sexo masculino e tiver mais de 21 anos. 
 
ALGORITMO "EX7" 
 VAR 
 NOME, SEXO : CARACTERE 
 ID, X : INTEIRO 
INICIO 
 PARA X DE 1 ATE 200 FACA 
 ESCREVAL ("DIGITE O NOME:") 
 LEIA (NOME) 
 ESCREVA ("DIGITE O SEXO (M/F):") 
 LEIA (SEXO) 
 ESCREVAL ("DIGITE A IDADE:") 
 LEIA (ID) 
 SE (SEXO = "M") E (ID > 21) ENTAO 
 ESCREVAL (NOME, " É DO SEXO MASCULINO E TEM MAIS DE 21 ANOS") 
 FIMSE 
 FIMPARA 
FIMALGORITMO 
 
8- Criar um algoritmo que entre com a idade de várias pessoas e imprima: 
a) Total de pessoas com menos de 21 anos; 
b) Total de pessoas com mais de 50 anos. 
 
Quando a idade lida for zero encerra a execução. 
 
ALGORITMO "EX8" 
 VAR 
 ID, TPM21, TPM50 : INTEIRO 
INICIO 
 TPM21 := 0 
 TPM50 := 0 
 ESCREVAL ("DIGITE A IDADE:") 
 LEIA (ID) 
 ENQUANTO ID <> 0 FACA 
 SE ID < 21 ENTAO 
 TPM21 := TPM21 + 1 
 SENAO 
 SE ID > 50 ENTAO 
 TPM50 := TPM50 + 1 
 FIMSE 
 FIMSE 
 ESCREVAL ("DIGITE A IDADE:") 
 LEIA (ID) 
 FIMENQUANTO 
 ESCREVAL ("TOTAL DE PESSOAS C/ IDADE MENOR QUE 21: ", TPM21) 
 ESCREVAL ("TOTAL DE PESSOAS C/ IDADE MAIOR QUE 50: ", TPM50) 
FIMALGORITMO 
 
9- Criar um algoritmo que entre com 100 números e imprima a média aritmética desses números. 
 
ALGORITMO "EX9" 
 VAR 
 NUM, SOMA, MD : REAL 
 X : INTEIRO 
INICIO 
 SOMA := 0 
 PARA X DE 1 ATE 100 FACA 
 ESCREVAL ("ENTRE COM O NÚMERO: ") 
LEIA (NUM) 
 SOMA := SOMA + NUM 
 FIMPARA 
 MD := SOMA /100 
 ESCREVAL ("A MÉDIA ARITMÉTICA:", MD) 
FIMALGORITMO 
 
10- Criar um algoritmo que possa ler um conjunto de pedidos de compra e calcule o valor total da compra. Cada 
pedido é composto pelos seguintes campos: número, preço e quantidade. O algoritmo deverá processar novos 
pedidos até que o usuário digite zero para número de pedido. 
 
ALGORITMO "EX10" 
 VAR 
 NUM, PRECO, QTD, VT : REAL 
INICIO 
 VT := 0 
 ESCREVAL ("DIGITE O NÚMERO DO PEDIDO: ") 
 LEIA (NUM) 
 ENQUANTO NUM <> 0 FACA 
 ESCREVAL ("DIGITE O PREÇO: ") 
 LEIA (PRECO) 
 ESCREVAL ("DIGITE A QUANTIDADE: ") 
 LEIA (QTD) 
 VT := VT + (PRECO * QTD) 
 ESCREVAL ("DIGITE O NÚMERO DO PEDIDO: ") 
 LEIA (NUM) 
 FIMENQUANTO 
 ESCREVAL ("VALOR TOTAL DA COMPRA: ", VT) 
FIMALGORITMO 
 
11- Criar um algoritmo que leia vários números e imprima o maior e o menor deles. Quando for lido o valor zero o 
finaliza o processamento. 
 
ALGORITMO "EX11" 
 VAR 
 NUM, MAIOR, MENOR : REAL 
INICIO 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 MENOR := NUM 
 MAIOR := NUM 
 ENQUANTO NUM <> 0 FACA 
 SE NUM < MENOR ENTAO 
 MENOR := NUM 
 SENAO 
 SE NUM > MAIOR ENTAO 
 MAIOR := NUM 
 FIMSE 
 FIMSE 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 FIMENQUANTO 
 ESCREVAL ("MENOR VALOR: ", MENOR) 
 ESCREVAL ("MAIOR VALOR: ", MAIOR) 
FIMALGORITMO 
 
12- Criar um algoritmo que imprima os 20 primeiros termos da série Fibonacci: 1, 1, 2, 3, 5, 8, 13, 21 ... 
 
ALGORITMO "EX12" 
 VAR 
 ANT, ATUAL, PROX, X : INTEIRO 
INICIO 
 ANT :=0 
 ATUAL := 1 
 PARA X DE 1 ATE 20 FACA 
 ESCREVA (ATUAL, " ") 
 PROX := ATUAL + ANT 
 ANT := ATUAL 
 ATUAL := PROX 
 FIMPARA 
FIMALGORITMO 
 
13- Criar um algoritmo que imprima a seguinte sequência: 1, 100, 3, 98, 5, 96, ..., 99, 2. 
 
ALGORITMO "EX13" 
 VAR 
 Y, X : INTEIRO 
INICIO 
 Y := 100 
 PARA X DE 1 ATE 99 PASSO 2 FACA 
 ESCREVA (X, " ", Y, " ") 
 Y := Y -2 
 FIMPARA 
FIMALGORITMO 
 
14- Criar um algoritmo que imprima a seguinte sequência: 1, 2, 2, 4, 3, 4, 4, 6, 5, 6, 6, 8, 7, 8, 8, 10, 9, 10, 10, 12. 
 
ALGORITMO "EX14" 
 VAR 
 Y, X : INTEIRO 
INICIO 
 Y := 2 
 PARA X DE 1 ATE 10 FACA 
 ESCREVA (X, " ", Y, " ") 
SE X MOD 2 <> 0 ENTAO // O INCREMENTO É FEITO APENAS QUANDO X FOR ÍMPAR 
 Y := Y +2 
 FIMSE 
 FIMPARA 
FIMALGORITMO 
 
15- Criar um algoritmo que imprima a tabuada de multiplicação de um determinado número lido (variando de 1 a 
10). 
 
ALGORITMO "EX15" 
 VAR 
 NUM, X : INTEIRO 
INICIO 
 ESCREVAL ("DIGITE UM NÚMERO: ") 
 LEIA (NUM) 
 PARA X DE 1 ATE 10 FACA 
 ESCREVAL (NUM, " X ", X, " = ", NUM * X) 
 FIMPARA 
FIMALGORITMO 
 
16- Criar um algoritmo para ler a nota da 1ª avaliação e 2ª avaliação de 100 alunos. Imprimir a listagem, 
contendo: nome e média da cada aluno, no final, informe a média geral da turma. 
 
ALGORITMO "EX16" 
 VAR 
 NT1, NT2, MD, MDG, SM : REAL 
 X : INTEIRO 
 NOME : CARACTERE 
INICIO 
 PARA X DE 1 ATE 100 FACA 
 ESCREVAL ("DIGITE O NOME: ") 
 LEIA (NOME) 
 ESCREVAL ("DIGITE A 1ª NOTA: ") 
 LEIA (NT1) 
 ESCREVA ("DIGITE A 2ª NOTA: ") 
 LEIA (NT2) 
 MD := (NT1 + NT2) /2 
 ESCREVAL (NOME, " OBTEVE MÉDIA: ", MD) 
 SM := SM + MD 
 FIMPARA 
 MDG := SM / 100 
 ESCREVAL ("MÉDIA GERAL: ", MDG) 
FIMALGORITMO 
 
17- Criar um algoritmo para efetuar a multiplicação de A e B usando o operador da soma. 
 
ALGORITMO "EX17" 
 VAR 
 A , B, X, MULT : INTEIRO 
INICIO 
 MULT := 0 
 ESCREVAL ("DIGITE O 1º NÚMERO: ") 
 LEIA (A) 
 ESCREVAL ("DIGITE O 2º NÚMERO: ") 
 LEIA (B) 
 PARA X DE 1 ATE A FACA 
 MULT := MULT + B 
 FIMPARA 
 ESCREVAL ("MULTIPLICAÇÃO: ", MULT) 
FIMALGORITMO 
 
18- Criar um algoritmo que leia um valor e escreva o seu fatorial. O fatorial de um número n é o produto de todos 
os seus antecessores, incluindo si próprio e excluindo o zero. Exemplo, fatorial de 5!: 5 x 4 x 3 x 2 x 1 = 120. 
 
ALGORITMO "EX18" 
 VAR 
 NUM, X, FAT: INTEIRO 
INICIO 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 FAT := NUM 
 PARA X DE NUM-1 ATE 1 PASSO -1 FACA 
 FAT := FAT * X 
 FIMPARA 
 ESCREVAL ("FATORIAL: ", FAT) 
FIMALGORITMO 
 
19- Criar um algoritmo que entre com um número e determine se o mesmo é um número primo ou não. O 
Número primo é divisível apenas por um e ele mesmo, por exemplo, o número 11 é primo. 
 
ALGORITMO "EX19" 
 VAR 
 NUM, X, CONT : INTEIRO 
INICIO 
 CONT := 0 
 ESCREVAL ("DIGITE O NÚMERO: ") 
 LEIA (NUM) 
 PARA X DE 1 ATE NUM FACA 
 SE NUM MOD X = 0 ENTAO 
 CONT := CONT + 1 
 FIMSE 
 FIMPARA 
 SE CONT = 2 ENTAO 
 ESCREVAL ("NÚMERO ", NUM, " É PRIMO") 
 SENAO 
 ESCREVAL ("NÚMERO ", NUM, " NÃO É PRIMO") 
 FIMSE 
FIMALGORITMO 
 
20- Uma pousada estipulou o preço para sua diária em R$ 100,00 e mais uma taxa de serviços diária de: 
 
a) R$ 15,00, se o número de dias for menor que 10; 
b) R$ 8,00, se o número de dias for maior ou igual a 10. 
 
Criar um algoritmo que entre com número do apartamento, nome e quantidade de dias da hospedagem para 
informar o nome e o valor da conta de cada cliente. O algoritmo encerra quando for lido o apartamento zero. 
 
ALGORITMO "EX20" 
 VAR 
 AP, QD : INTEIRO 
 TX ,VC : REAL 
 NOME : CARACTERE 
INICIO 
 ESCREVAL ("DIGITE O APARTAMENTO: ") 
 LEIA (AP) 
 ENQUANTO AP <> 0 FACA 
 ESCREVAL ("DIGITE O NOME: ") 
 LEIA (NOME) 
 ESCREVAL ("DIGITE A QUANTIDADE DE DIAS DA HOSPEDAGEM: ") 
 LEIA (QD) 
 SE QD < 10 ENTAO 
 TX := QD * 15 
 SENAO 
 TX := QD * 8 
 FIMSE 
 VC := QD * 100 + TX 
 ESCREVAL ("O VALOR DA CONTA DO CLIENTE ", NOME, ": ", VC) 
 ESCREVAL ("DIGITE O APARTAMENTO: ") 
 LEIA (AP) 
 FIMENQUANTO 
FIMALGORITMO 
 
21- Os alunos de informática tiveram cinco provas: 1, 2, 3, 4 e 5. Criar um algoritmo que entre com a matrícula, 
nome e as notas das provas para imprimir: 
 
a) Nome dos alunos que tiveram todas as notas dentro da média; 
b) Nome dos alunos que tiveram as notas da 1ª e 4ª prova dentro da média; 
c) A porcentagem dos alunos que tiveram notas da 3ª prova dentro da média. 
 
Obs.: A média da faculdade é 7,0 e O algoritmo encerra quando for lido a matrícula zero. 
 
ALGORITMO "EX21" 
 VAR 
 NT1, NT2, NT3, NT4, NT5, PORC :REAL 
 CONTG, CONT, MAT : INTEIRO 
 NOME : CARACTERE 
INICIO 
 CONTG := 0 
 CONT := 0 
 ESCREVAL ("DIGITE A MATRÍCULA: ") 
 LEIA (MAT) 
 ENQUANTO MAT<> 0 FACA 
 ESCREVAL ("DIGITE O NOME: ") 
 LEIA (NOME) 
 ESCREVAL ("DIGITE A 1ª NOTA: ") 
 LEIA (NT1) 
 ESCREVAL ("DIGITE A 2ª NOTA: ") 
 LEIA (NT2) 
 ESCREVAL ("DIGITE A 3ª NOTA: ") 
 LEIA (NT3) 
 ESCREVAL ("DIGITE A 4ª NOTA: ") 
 LEIA (NT4) 
 ESCREVAL ("DIGITE A 5ª NOTA: ") 
 LEIA (NT5) 
 SE (NT1 >=7) E (NT2 >= 7) E (NT3 >= 7) E (NT4 >= 7) E (NT5 >= 7) ENTAO 
 ESCREVAL (NOME, " OBTEVE TODAS AS NOTAS ACIMA DA MÉDIA") 
 FIMSE 
 SE (NT1 >= 7) E (NT4 >= 7) ENTAO 
 ESCREVAL (NOME, " OBTEVE NOTAS DA 1ª E 4ª AV. ACIMA DA MÉDIA") 
 FIMSE 
 SE (NT3 >= 7) ENTAO 
 CONT := CONT + 1 
 FIMSE 
 CONTG := CONTG + 1 
 ESCREVAL ("DIGITE A MATRÍCULA: ") 
 LEIA (MAT) 
 FIMENQUANTO 
 PORC := CONT / CONTG * 100 
 ESCREVAL ("PERCENTUAL DE ALUNOS COM NOTA ACIMA DA MÉDIA NA 3ª AVALIAÇÃO: ", PORC) 
FIMALGORITMO 
 
22- Criar um algoritmo que ajude o DETRAN a saber o total de recursos que foram arrecadados com a aplicação 
de multas de trânsito. 
 
O algoritmo deve ler as seguintes informações para cada motorista: número da carteira do motorista, número de 
multas e o valor de cada uma das multas. 
 
Deve ser impresso o número da carteira e o valor da dívida para cada motorista. No final da leitura exibir o total 
de recursos arrecadados (somatório de todas as multas) e número da carteira que obteve o maior número de 
multas. O algoritmo encerra ao ler o número da carteira de valor zero. 
 
ALGORITMO "EX22" 
 VAR 
 VM, TM, TGM : REAL 
 X, NC, QM, MQM, NCI : INTEIRO 
INICIO 
 TM := 0 
 MQM := 0 
 TGM := 0 
 ESCREVAL ("DIGITE O NÚMERO DA CARTEIRA DE MOTORISTA: ") 
 LEIA (NC) 
 ENQUANTO NC <> 0 FACA 
 ESCREVAL ("DIGITE A QUANTIDADE DE MULTAS: ") 
 LEIA (QM) 
 SE QM > MQM ENTAO 
 MQM := QM 
 NCI := NC 
 FIMSE 
 PARA X DE 1 ATE QM FACA 
 ESCREVAL ("DIGITE O VALOR DA ", X, "ª MULTA: ") 
 LEIA (VM) 
 TM := TM + VM 
 FIMPARA 
 ESCREVAL ("A CARTEIRA DE NÚMERO: ", NC, " TEM UMA DÍVIDA DE: ", TM) 
 TGM := TGM + TM 
 TM := 0 
 ESCREVAL ("DIGITE O NÚMERO DA CARTEIRA DE MOTORISTA: ") 
 LEIA (NC) 
 FIMENQUANTO 
 ESCREVAL ("O TOTAL GERAL DE MULTAS: ", TGM) 
 ESCREVA ("O NÚMERO DA CARTEIRA COM MAIOR INFRAÇÃO: ", NCI) 
FIMALGORITMO 
 
23- Criar um algoritmo que receba idade, altura e peso de várias pessoas. Calcule e imprima: 
 
a) A Quantidade de pessoas com idade superior a 50 anos; 
b) A média das alturas das pessoas com idade entre 10 e 20 anos; 
c) A porcentagem de pessoas com peso inferior a 40 quilos entre todas as pessoas analisadas. 
 
Obs.: O algoritmo encerra quando a idade lida for zero. 
 
ALGORITMO "EX23" 
VAR 
 ID, QPIS50, QPIE10E20, QPPI40, QGP : INTEIRO 
 A, P, TALT, MDALT, PORC : REAL 
INICIO 
 QPIS50 := 0 
 QPPI40 := 0 
 QPIE10E20 := 0 
 QGP := 0 
 TALT := 0 
 ESCREVAL ("DIGITE A IDADE: ") 
 LEIA (ID) 
ENQUANTO ID <> 0 FACA 
 ESCREVAL ("DIGITE A ALTURA: ") 
 LEIA (A) 
 ESCREVAL ("DIGITE O PESO: ") 
 LEIA (P) 
 SE (ID > 10) E (ID < 20) ENTAO 
 QPIE10E20 := QPIE10E20 + 1 
 TALT := TALT + A 
 SENAO 
 SE ID > 50 ENTAO 
 QPIS50 := QPIS50 + 1 
 FIMSE 
 FIMSE 
 SE P < 40 ENTAO 
 QPPI40 := QPPI40 + 1 
 FIMSE 
 QGP := QGP + 1 
 ESCREVAL ("DIGITE A IDADE: ") 
 LEIA (ID) 
 FIMENQUANTO 
 MDALT :=TALT / QPIE10E20 
 PORC := QPPI40 / QGP * 100 
 ESCREVAL ("A QUANTIDADE DE PESSOAS COM IDADE SUPERIOR A 50 ANOS: ", QPIS50) 
 ESCREVAL ("A MÉDIA DAS ALTURAS DAS PESSOAS COM IDADE ENTRE 10 E 20 ANOS: ", MDALT) 
 ESCREVAL ("A PORCENTAGEM DE PESSOAS COM PESO INFERIOR A 40 QUILOS: ", PORC) 
FIMALGORITMO 
 
24- Criar um algoritmo que receba a idade e o estado civil (C- casado, S- Solteiro, V- viúvo, e D- desquitado) de 
várias pessoas. Calcule e imprima: 
 
a) A quantidade de pessoas casadas; 
b) A quantidade de pessoas solteiras; 
c) A média das idades das pessoas viúvas; 
d) A porcentagem de pessoas desquitadas dentre todas as pessoas analisadas. 
 
Obs.: O algoritmo encerra quando a idade lida for zero. 
 
ALGORITMO "EX24" 
 VAR 
 ID, QC, QS, QV, QD, TID, QGP : INTEIRO 
 MDID, PORC : REAL 
 EC : CARACTERE 
INICIO 
 QC := 0 
 QS := 0 
 QV := 0 
 QGP := 0 
 TID := 0 
 ESCREVAL ("DIGITE A IDADE: ") 
 LEIA (ID) 
 ENQUANTO ID <> 0 FACA 
 ESCREVAL ("DIGITE O ESTADO CIVIL: ") 
 LEIA (EC) 
 ESCOLHA EC 
 CASO "C" 
 QC := QC + 1 
 CASO "S" 
 QS := QS + 1 
 CASO "V" 
 QV := QV + 1 
 TID := TID + ID 
 CASO "D" 
 QD := QD + 1 
 FIMESCOLHA 
 QGP := QGP + 1 
 ESCREVAL ("DIGITE A IDADE: ") 
 LEIA (ID) 
 FIMENQUANTO 
 MDID :=TID / QV 
 PORC :=QD / QGP *100 
 ESCREVAL ("A QUANTIDADE DE PESSOAS CASADAS: ", QC) 
 ESCREVAL ("A QUANTIDADE DE PESSOAS SOLTEIRAS: ", QS) 
 ESCREVAL ("A MÉDIA DAS IDADES DAS PESSOAS VIÚVAS: ", MDID) 
 ESCREVAL ("A PORCENTAGEM DE PESSOAS DESQUITADAS: ", PORC) 
FIMALGORITMO 
 
25- Um pesquisa de opinião realizada no Rio de Janeiro teve as seguintes perguntas: 
 
Qual seu time de coração? 
1- Fluminense 
2- Botafogo 
3- Vaso 
4- Flamengo 
5- Outros 
 
Onde você mora? 
1- RJ 
2- Niterói 
3- Outros 
 
Qual o seu salário? 
 
Criar um algoritmo que imprima: 
a) O número de torcedores por clube; 
b) A média salarial dos torcedores do Botafogo; 
c) A média de pessoas moradoras do Rio de Janeiro que torcem para outros clubes; 
d) O número de pessoasde Niterói torcedoras do Fluminense. 
 
Obs.: O algoritmo acaba quando se digita zero para o time. 
 
ALGORITMO "EX25" 
VAR 
QTFLU, QTFLA, QTVAS, QTBOT, QTOUT, QMRJ, QMRJTO, QTFLUN, TIME, CIDADE : INTEIRO 
 SAL, TSAL, MDSAL, MDPRJ: REAL 
INICIO 
 QTFLU := 0 
 QTFLA := 0 
 QTVAS := 0 
 QTBOT := 0 
 QMRJ := 0 
 TSAL := 0 
 QTFLUN := 0 
 QTOUT := 0 
 QMRJTO := 0 
 ESCREVAL ("DIGITE O TIME (1-FLU, 2-BOT, 3-VAS, 4-FLA E 5-OUT): ") 
 LEIA (TIME) 
 ENQUANTO TIME <> 0 FACA 
 ESCREVAL ("DIGITE A CIDADE QUE MORA (1-RJ, 2-NIT, 3-OUT):") 
 LEIA (CIDADE) 
 ESCREVAL ("DIGITE O SALÁRIO: ") 
 LEIA (SAL) 
 ESCOLHA (TIME) 
 CASO 1 
 QTFLU := QTFLU + 1 
 SE CIDADE = 2 ENTAO 
 QTFLUN := QTFLUN + 1 
 FIMSE 
 CASO 2 
 QTBOT := QTBOT + 1 
 TSAL := TSAL + SAL 
 CASO 3 
 QTVAS := QTVAS +1 
 CASO 4 
 QTFLA := QTFLA + 1 
 OUTROCASO 
 QTOUT := QTOUT + 1 
 SE CIDADE = 1 ENTAO 
 QMRJTO := QMRJTO + 1 
 FIMSE 
 FIMESCOLHA 
 SE CIDADE = 1 ENTAO 
 QMRJ := QMRJ + 1 
 FIMSE 
 ESCREVAL ("DIGITE O TIME (1-FLU, 2-BOT, 3-VAS, 4-FLA E 5-OUT): ") 
 LEIA (TIME) 
 FIMENQUANTO 
 MDSAL := TSAL / QTBOT 
 MDPRJ := QMRJ / QMRJTO 
 ESCREVAL ("TOTAL DE TORCEDORES DO FLUMINENSE: ", QTFLU) 
 ESCREVAL ("TOTAL DE TORCEDORES DO BOTAFOGO: ", QTBOT) 
 ESCREVAL ("TOTAL DE TORCEDORES DO VASCO: ", QTVAS) 
 ESCREVAL ("TOTAL DE TORCEDORES DO FLAMENGO: ", QTFLA) 
 ESCREVAL ("TOTAL DE TORCEDORES DE OUTROS TIMES: ",QTOUT) 
 ESCREVAL ("A MÉDIA SALARIAL DOS TORCEDORES DO BOTAFOGO: ", MDSAL) 
 ESCREVAL ("A MÉDIA DE PESSOAS MORADORAS DO RJ QUE TORCEM PARA OUTROS CLUBES: ", MDPRJ) 
 ESCREVAL ("O NÚMERO DE PESSOAS DE NITERÓI TORCEDORAS DO FLUMINENSE: ", QTFLUN) 
FIMALGORITMO